Tcl

Z Wikipedie, otevřené encyklopedie
Skočit na: Navigace, Hledání
Tcl
Paradigma Multiparadigmatický: imperativní, strukturovaný, procedurální, funkcionální, objektově orientovaný, řízený událostmi
Vznikl v 1988
Autor John Ousterhout
Vývojář John Ousterhout, Tcl Core Team
Poslední verze 8.6.7 (9. srpna 2017)
Typová kontrola dynamická
Hlavní implementace ActiveTcl
Ovlivněn jazyky Awk, Lisp
Ovlivnil jazyky PHP,[1] Tea, PowerShell[2]
Licence Stylu BSD
Web www.tcl.tk

Tcl (vyslovuje se „tý-sý-el“ nebo „tykl“, název je zkratka z Tool Command Language) je jednoduchý, ale účinný skriptovací jazyk, který v roce 1988 vytvořil John Ousterhout. Přes svoje stáří a nezvyklou syntaxi je snadno zvládnutelný, a díky nízkým nárokům na hardware je oblíbeným jazykem především pro testování softwaru, programování vestavěných systémů a prototypování. V roce 1991 byl doplněn grafickým frameworkem Tk a výsledný systém nazývaný Tcl/Tk se stal až do nástupu Qt a GTK+ jedním z nejoblíbenějších nástrojů pro vytváření grafických uživatelských rozhraní; knihovna Tk byla zpřístupněna v různých skriptovacích (Perl, Python, Ruby) i kompilovaných jazycích.

Vlastnosti[editovat | editovat zdroj]

Základní vlastnosti:

  • imperativní jazyk – program se skládá pouze z příkazů
  • všechny příkazy (i řídicí struktury) mají jednotnou strukturu v prefixové notaci (výrazy ale používají obvyklou infixovou notaci)
  • příkazy mohou mít proměnný počet parametrů
  • všechny příkazy mohou být dynamicky předefinovány nebo přetíženy
  • všechny datové typy i text programu mohou být reprezentovány jako textové řetězce
  • událostmi řízené rozhraní pro sokety a soubory; lze používat časové a uživatelem definované události
  • viditelnost proměnných implicitně omezena na lexikální oblast platnosti, příkazy uplevelupvar dovolují procedurám komunikovat s obklopujícími funkcemi
  • všechny příkazy definované přímo jazykem Tcl generují při chybném použití chybová hlášení
  • snadná rozšiřitelnost pomocí jazyka C, C++, Java nebo samotného Tcl
  • interpretovaný jazyk používající bytecode, text programu se dá vytvářet za běhu
  • plná podpora Unicode 3.1 od roku 1999
  • přenositelnost – samotný jazyk, i mnoho knihoven (včetně Tk) jsou nezávislé na platformě (Windows, Unix, Linux, Mac)
  • úzká integrace s knihovnou grafického uživatelského rozhraní Tk

Spuštění Tcl[editovat | editovat zdroj]

Základní interpret jazyka Tcl – tclsh – lze spustit bez parametrů a s Tcl pracovat interaktivně:

tclsh
% expr 22/7
3
% expr 22/7.
3.142857142857143
% expr 4*atan(1)
3.141592653589793
% string length "nejneobhospodařovatelnějšími"
28
% exit

– procento (%) je nápověda interpretu, expr je příkaz pro vyhodnocení matematických výrazů, lomítko je operátor dělení (pro dělení celých čísel se používá celočíselné dělení se zbytkem, použitím tečky se vynutí reálné dělení), hvězdička je operátor násobení; pro ukončení interpretu lze použít příkaz exit nebo znak konce souboru, kterým je v Microsoft Windows a v MS-DOSu klávesová kombinace Ctrl-Z, v Unixu Ctrl+D. Aby bylo možné editovat příkazy pomocí kurzorových kláves, musí být nainstalován balíček tclreadline[3]; i bez něj lze příkazem history vypsat seznam zadaných příkazů a zvolený příkaz znovu vyvolat zadáním vykřičníku a čísla příkazu.

Druhý interpret – wish – je určený pro programy používající grafické uživatelské rozhraní:

wish
% wm title . "Hlavní okno"
% wm minsize . 320 200
% label .l -text "Nápis v hlavním okně"
.l
% pack .l -padx 40 -pady 20
% toplevel .w2 
.w2
% wm title .w2 "Druhé okno"
% label .w2.l -text "Nápis v druhém okně"
.w2.l
% pack .w2.l -padx 10 -pady 10
%

– spuštěním wish se otevře hlavní okno okno aplikace; příkazy začínající wm slouží pro komunikaci se správcem oken: wm title změní text v záhlaví okna a wm minsize předepíše jeho minimální velikost (šířka 320 pixelů a výška 200 pixelů); příkaz label připraví nápis, který se provedením příkazu pack zobrazí uvnitř okna; příkaz toplevel vytvoří druhé okno, kterému se dalšími příkazy také změní text v záhlaví a ve kterém se vypíše další text; parametry začínající tečkou jsou obdobou cest používaných pro navigaci ve stromové struktuře adresářů na disku: samotná tečka označuje hlavní okno, .l je prvek pojmenovaný l ve hlavním okně, .w2 je druhé okno a .w2.l je prvek ve druhém okně (na konkrétních jménech l a w2 nezáleží). Příkazy vytvářející grafické prvky, jako label a toplevel, vracejí jméno prvku, které lze uložit do proměnných a používat v dalších příkazech.

Nápověda interpretu % již nebude dále uváděna.

Obvyklejší přístup je ale spouštění předem připravených programů neboli skriptů:

tclsh program.tcl parametr parametr ...

Parametry skriptu jsou dostupné jako seznam v proměnné argv; počet parametrů lze tedy zjistit pomocí llength $argv. Další možností je čtení proměnné argc z globálního jmenného prostoru, tedy $::argc. Jméno spuštěného skriptu je v proměnné argv0.

Souborům s programy v jazyce Tcl se obvykle dává přípona .tcl. Aby v Unixu bylo možné pouštět Tcl skripty pouze zadáním jejich jména, je potřeba dát souboru se skriptem právo execute a na jeho začátek přidat první čtyři řádky z následující ukázky:

#!/bin/sh
# -*- tcl -*-
# The next line is executed by /bin/sh, but not tcl \
exec tclsh "$0" ${1+"$@"}

puts "Hello, world!"

První řádek díky konstrukci Shebang zajistí, že se skript začne interpretovat programem /bin/sh; provedením příkazu exec se spustí tclsh, který začne číst soubor se skriptem zase od začátku, ale řádek s příkazem exec považuje za pokračování komentáře z předchozího řádku díky jeho zakončení obráceným lomítkem.

Syntaxe a základní sémantika[editovat | editovat zdroj]

Program (skript) v Tcl je tvořen posloupností příkazů. Každý příkaz začíná jménem příkazu, za kterým mohou následovat argumenty (parametry) oddělované od sebe navzájem i od jména příkazu vždy alespoň jednou mezerou nebo tabulátorem. Příkaz je ukončen koncem řádku nebo středníkem. Jména příkazů v Tcl nejsou vyhrazená slova, ani nemají v jazyce žádné zvláštní postavení; jsou to obyčejné, nijak neprivilegované, funkce v knihovně. Příkazy mohou mít proměnný počet argumentů.

příkaz argument1 argument2 ... argumentN

Pokud argumenty obsahují bílé znaky, musí být uzavřeny ve dvojitých uvozovkách nebo ve složených závorkách – pak může být argument i víceřádkový; pokud ale chcete odřádkovat mezi argumenty, je nutné bezprostředně před odřádkování napsat zpětné lomítko.

Symboly se zvláštním významem[editovat | editovat zdroj]

  • $ – vrací hodnotu proměnné, jejíž jméno je uvedeno za znakem dolar
  • [] – závorky včetně obsahu nahradí výstupem Tcl příkazu, který je v závorkách uzavřen
  • "" – obsah uvozovek považuje za jediný argument, přitom vyhodnocuje vnořené konstrukce s $, [] a \
  • {} – obsah závorek považuje za jediný argument, ale na rozdíl od uvozovek nevyhodnocuje konstrukce se speciální znaky uvnitř
  • \ – ruší zvláštní význam následujícího znaku nebo vytváří řídicí znak nebo znak se zadaným kódem
  • # – uvozuje komentář, který končí s koncem řádku; lze použít pouze v místě, kde může začínat příkaz

Apostrofy nemají v Tcl žádný zvláštní význam. Kulaté závorky se používají pro přístup k prvkům asociativních polí a pro vyjádření priority v aritmetických výrazech.

Příkaz puts[editovat | editovat zdroj]

Příkaz puts vypíše zadaný řetězec (který musí tvořit jedno slovo, proto je vhodné jej vždy uzavírat do uvozovek) následovaný znakem konce řádku, implicitně na standardní výstup (kanál stdout):

puts "Hello, world!"

Pokud puts nemá po vypsání řetězce odřádkovat, je potřeba před řetězcem použít volbu -nonewline:

puts -nonewline "Hodnota proměnné i: "
puts $i

Před vypisovaným řetězcem lze uvést jméno výstupního kanálu (nebo proměnnou, která se odkazuje na soubor):

puts stderr "Chyba!"

Proměnné a příkaz set[editovat | editovat zdroj]

Pro přiřazení hodnoty do proměnné slouží příkaz set; pro získání obsahu proměnné je nutné před její jméno napsat znak dolar:

% set x 5
5
% puts "Hodnota proměnné x je $x."
Hodnota proměnné x je 5.

Pokud je příkaz set zadán v příkazovém řádku tclsh (tj. při interaktivním provádění), vypisuje se přiřazovaná hodnota; při provádění programu ne.

Přiřazení hodnoty výrazu do proměnné není tak jednoduché; je potřeba použít příkaz expr a hranaté závorky pro dosazení výsledku příkazu do jiného příkazu:

% set stupnu_Fahrenheita 451
451
% set stupnu_Celsia [expr {($stupnu_Fahrenheita-32)/1.8}]
232.77777777777777

Před otevírací hranatou i složenou závorkou musí být mezera; první odděluje parametry příkazu set, druhá jméno příkazu expr od parametru.

Aby se odlišilo jméno proměnné od okolního textu, lze jej uzavřít do složených závorek ${jmeno}:

% set a 2
2
% set b 3
3
% puts "${a}x$b=[expr {$a*$b}]"
2x3=6

Tcl není staticky typovaný jazyk: každá proměnná může obsahovat hodnotu libovolného typu – např. celé číslo, reálné číslo, řetězec, seznam, jméno příkazu nebo slovník; hodnoty se převádějí na jiné typy podle potřeby automaticky (s omezeními danými syntaxí). Hodnoty jsou ale vždy konstantní (anglicky immutable); operace, které vypadají, že mění hodnoty, ve skutečnosti pouze vrací jinou hodnotu.

Asociativní pole[editovat | editovat zdroj]

Asociativní pole je složená datová struktura, ve které se pro přístup k jednotlivým položkám používá klíč, kterým může být libovolný textový řetězec. S prvky asociativních polí se pracuje stejně jako s jednoduchými proměnnými:

set hlavni_mesta(ČR) "Praha"
set hlavni_mesta(Slovensko) "Bratislava"
set hlavni_mesta(Polsko) "Varšava"
set hlavni_mesta(Německo) "Berlín"
set hlavni_mesta(Rakousko) "Vídeň"

set stat Slovensko
puts "Hlavní městem státu $stat je $hlavni_mesta($stat)."

Asociativní pole lze také vytvořit pomocí příkazu array set:

array set hlavni_mesta {
  "ČR"         "Praha"
  "Slovensko"  "Bratislava"
  "Polsko"     "Varšava"
  "Německo"    "Berlín"
  "Rakousko"   "Vídeň"
}

set stat Slovensko
puts "Hlavní městem státu $stat je $hlavni_mesta($stat)."

Oba skripty vypíšou:

Hlavní městem státu Slovensko je Bratislava.

Operátory seskupení[editovat | editovat zdroj]

Před provedením každého příkazu Tcl provede vyhodnocení proměnných a vnořených příkazů (tzv. substituce nebo expanze). Substituci lze řídit pomocí operátorů seskupení. Jazyk Tcl má 3 operátory seskupení:

  • Uvozovky ""
  • Složené závorky {}
  • Hranaté závorky []

Operátory seskupení propůjčují jazyku Tcl nezaměnitelný charakter, jsou však zároveň i příčinou, proč se mu mnoho programátorů vyhýbá.

Uvozovky[editovat | editovat zdroj]

Uvozovky se chovají stejně jako v mnoha jiných skriptovacích jazycích: vytvářejí řetězec z posloupnosti slov a zároveň nezabraňují expanzi proměnných ani vyhodnocování příkazů zapsaných v hranatých závorkách. Pokud se mají do řetězce vložit uvozovky, je nutné před nimi napsat obrácené lomítko; obrácené lomítko také ruší význam dolaru jako prostředku pro expanzi hodnoty proměnné:

puts "Prvek $i pole \$arr má hodnotu \"$arr($i)\"."

Pokud je v proměnné i hodnota 8, a prvek pole $arr s indexem 8 (indexem může být i řetězec) obsahuje řetězec "osmička", vypíše se

Prvek 8 pole $arr má hodnotu "osmička".

V uvozovkách mají některé posloupnosti začínající znakem obrácené lomítko význam řídicích nebo jiných znaků:

Posloupnost Význam
\n Znak nový řádek (line feed)
\r Znak návrat vozíku (carriage return)
\t Znak tabelátor (tab)
\v Znak vertikální tabelátor (vertical tab)
\a Znak zvonek (bell)
\b Znak backspace
\0nn Znak se zadaným kódem (v osmičkové soustavě)
\uHHHH Unicode znak U+HHHH
\xHH Znak se zadaným kódem (v šestnáctkové soustavě)

Hranaté závorky[editovat | editovat zdroj]

Do hranatých závorek lze zapsat libovolný příkaz Tcl včetně parametrů; příkaz v hranatých závorkách se provede před provedením příkazu, ve kterém je použit, a hranaté závorky se nahradí výstupem, který vyprodukuje. V následujícím příkladu je použit příkaz clock seconds, který vrací počet sekund od 1. 1. 1970 a příkaz clock format, který tento údaj zformátuje podle parametru uvedeného za volbou -format:

puts "Od 1. ledna 1970 uplynulo [clock seconds] sekund;"
puts "Je rok [clock format [clock seconds] -format "%Y"]."

vypíše

Od 1. ledna 1970 uplynulo 1366380049 sekund;
Je rok 2013.

Jak je vidět hranaté závorky a uvozovky lze vnořovat.

Nejčastější příkaz, který se píše do hranatých závorek, je příkaz expr, který vyhodnocuje aritmetické výrazy:

set vyraz "1+2+3+4+5+6+7+8+9+10"
set vysledek [ expr $vyraz ]
puts "Součet $vyraz je $vysledek."

Vypíše

Součet 1+2+3+4+5+6+7+8+9+10 je 55.

Substituce pomocí hranatých závorek umožňuje použít výsledek jednoho příkazu jako argument dalšího příkazu. Pokud se má vyvolat příkaz jako funkce, která vrací hodnotu, musí se vždy uzavřít do hranatých závorek.

Tcl nepotřebuje operátor pro spojení řetězců, protože stačí jenom zapsat proměnné nebo příkazy v hranatých závorkách za sebe. Na rozdíl od unixových interpretů příkazů vyhodnocuje Tcl každý řetězec pouze jednou (pokud skript přímo nepředepisuje opakované vyhodnocení), což trochu komplikuje interaktivní použití, ale zprůhledňuje chování ve skriptech (např. mezery ve jméně souboru nepůsobí potíže známé z unixových shellů).

Složené závorky[editovat | editovat zdroj]

Složené závorky se chovají jako apostrofy v unixových interpretech příkazů a některých skriptovacích jazycích – jejich obsah se bere jako jedno slovo a nijak se neexpanduje (jen se ignoruje konec řádku, před kterým je zpětné lomítko). Složené závorky se mohou používat pro zápis řetězců, které se mají interpretovat přesně tak, jak jsou zapsány, v Tcl však mají mnohem širší použití – pro zápis řídicích struktur. Cyklus s testem na začátku se v Tcl zapisuje jako příkaz while, za kterým následují dvě slova – první je podmínka, druhé je tělo cyklu. Tcl nevyžaduje žádné závorky, do kterých by se podmínka a tělo cyklu uzavíralo, ale nejsnazší způsob, jak podmínku i tělo cyklu zapsat jako jedno slovo, je uzavřít je do složených závorek. Díky tomu se zápis while cyklu v Tcl podobá zápisu v jazyce C. Podobným způsobem se zapisuje definice funkce (první parametr za slovem proc je jméno procedury nebo funkce, druhý seznam parametrů, třetí tělo funkce), podmíněný příkaz (první parametr za slovem if je podmínka, druhým seznam příkazů, které se mají provést, je-li podmínka splněna, pak mohou následovat části elseif a else).

Do složených závorek se také uzavírají matematické výrazy vyhodnocované příkazem expr.

Pokud by se v příkazu puts použitém v části „Uvozovky“ nahradily vnější uvozovky složenými závorkami:

puts {Prvek $i pole \$arr má hodnotu \"$arr($i)\".}

výsledný výstup by vypadal značně odlišně; pravděpodobně úplně jinak, než bylo zamýšleno:

Prvek $i pole \$arr má hodnotu \"$arr($i)\".

Pokud jsou složené závorky vnořeny do jiných složených závorek, hranatých závorek nebo uvozovek, chovají se jako normální znak:

puts "Prvek {$i} pole \$arr má hodnotu {$arr($i)}."

vypíše

Prvek {8} pole $arr má hodnotu {osmička}.

Do složených závorek se uzavírají výrazy v příkazu expr, aby se zabránilo dvojí expanzi jména proměnných:

set i 10
set d "\$i"
puts [ expr 2*$d ]

Řídicí struktury[editovat | editovat zdroj]

V Tcl jsou dostupné obvyklé řídicí struktury:

  • if elseif elsepodmíněný příkaz
  • switch – vícecestné větvení
  • while – cyklus s testem na začátku
  • for – cyklus s řídicí proměnnou
  • foreach – cyklus přes prvky seznamu

Díky vynalézavému použití složených závorek je zápis řídicích struktur podobný jako v jazyce C; v Tcl se však do složených závorek píšou nejen příkazy, ale i podmínky. Interpretu Tcl je skutečnosti jedno, jaké operátory seskupení se použijí (a jestli vůbec nějaké). Vyžaduje pouze, aby slova uvozující jednotlivé konstrukce měly správný počet argumentů/parametrů. Například v příkazu cyklu while musí být za jménem příkazu dva argumenty: první je podmínka, druhý tělo cyklu. A nejjednodušším způsobem, jak sdělit Tcl, že určitý text má považovat za jeden parametr, je uzavřít jej do složených závorek. Protože parametry musí být odděleny aspoň jednou mezerou, musí být vně složených závorek (tj. před { a za }) vždy aspoň jeden bílý znak (mezera nebo tabelátor). Otevírací závorka těla cyklu musí být na stejném řádku jako podmínka (nebo musí být předchozí řádek zakončen zpětným lomítkem).

Podmíněný příkaz[editovat | editovat zdroj]

Následující program ukazuje syntaxi podmíněného příkazu v Tcl; část else je nepovinná, příkaz může mít libovolný počet částí elseif:

if {$i > 0} {
  puts "$i je kladné číslo"
} elseif {$i == 0} {
  puts "$i je nula"
} else {
  puts "$i je záporné číslo"
}

While cyklus[editovat | editovat zdroj]

Následující ukázka použití while příkazu počítá Ludolfovo číslo podle vzorce

kde funkce arkus tangens se počítá pomocí Taylorova vzorce

(pro )
set platnych_mist 12
set epsilon "1e-$platnych_mist"
set znam 1.0
set moc2 [expr {1.0/2.0}]
set moc3 [expr {1.0/3.0}]
set n 1
set clen [expr {$moc2+$moc3}]
set suma $clen
while {abs($clen)>$epsilon} {
    incr n 2
    set znam [expr {-$znam}]
    set moc2 [expr {$moc2/4.0}]
    set moc3 [expr {$moc3/9.0}]
    set clen [expr {$znam/$n*($moc2+$moc3)}]
    set suma [expr {$suma+$clen}]
}
puts "Ludolfovo číslo: [format "%.${platnych_mist}G" [expr {4.0*$suma}]]"

Příkaz incr zvětší hodnotu proměnné, která je jeho prvním parametrem, o hodnotu zadanou druhým parametrem (nebo o 1, pokud druhý parametr chybí).

Pro ukončení provádění cyklu lze použít příkaz break.

For cyklus[editovat | editovat zdroj]

V případě for cyklu se do vlastních složených závorek dává každý ze tří výrazů, které se v jazyce C píšou do kulatých závorek a oddělují středníky:

for { set i 1 } { $i <= 10 } { incr i } {
  puts "$i"
}

Pro ukončení provádění cyklu lze použít příkaz break, pro zahájení dalšího průchodu cyklem příkaz continue. V Tcl existuje i příkaz cyklu přes všechny prvky seznamu foreach, který je popsán u seznamů.

Definice funkcí[editovat | editovat zdroj]

Funkce se v Tcl definují příkazem proc, za kterým následují dvojí složené závorky; první obsahují seznam parametrů (oddělených mezerami), druhé tělo funkce. Pokud má funkce vracet návratovou hodnotu, lze použít příkaz return (jinak vrací výsledek posledního provedeného příkazu). Naprogramovat výpočet faktoriálu rekurzivně sice není ideální, ale je to možné i v Tcl. Všimněte si, že Tcl umožňuje, aby jméno funkce byl vykřičník:

proc ! { n } {
    if {$n <= 1} {
        set res 1
    } else {
        set res [ expr {$n * [ ! [ expr { $n - 1}] ]} ]
    }
    return $res
}

for { set n 1 } { $n <= 20 } { incr n } {
  puts "$n! = [ ! $n ]"
}

Vhodnější výpočet faktoriálu bez rekurze by mohl vypadat takto:

proc ! { n } {
    set res 1
    for { set k 2 } { $k <= $n } { incr k } {
        set res [expr {$res*$k}]
    }
    return $res
}

for { set n 1 } { $n <= 20 } { incr n } {
  puts "$n! = [ ! $n ]"
}

Uživatelem definované funkce se volají stejně jako ostatní příkazy – parametry se píšou za jméno funkce a od jména funkce i sebe navzájem se oddělují mezerami nebo bílými znaky. Proto při volání funkce faktoriál není možné psát (jako v matematice) vykřičník za výraz, z něhož se má faktoriál počítat.

Většina příkazů jazyka Tcl jsou funkce s proměnným počtem parametrů. To platí i o příkazech ve standardní knihovně. Příkaz proc (konstruktor pro vytváření procedur/funkcí) umožňuje definovat implicitní hodnoty pro argumenty, které nebudou použity ve volání procedury, a parametr obsahující všechny argumenty, což umožňuje zpracování proměnného počtu argumentů ve funkcích.

Přístup k globálním proměnným[editovat | editovat zdroj]

Proměnné použité mimo funkci nejsou uvnitř funkce viditelné. Pro jejich zpřístupnění lze uvnitř funkce použít příkaz

global proměnná

Modifikace parametrů funkce[editovat | editovat zdroj]

Pokud mají být změny hodnot některého z parametrů funkce viditelné i po opuštění funkce, je nutné použít předávání parametrů odkazem. V tcl lze použít následující konstrukci:

# Funkce vrátí kód bytu (0-255) z pozice idx v řetězci buffer a zvětší idx o 1
# Je-li idx >= než délka bufferu, vrátí -1 a idx nezmění
proc get_first_octet { buffer idx } {
    # na parametr idx se budeme odkazovat pomocí $pos
    upvar 1 $idx pos
    if { $pos < [string length $buffer] } {
        binary scan [string index $buffer $pos] c octet
        incr pos
        return [expr {$octet & 0xFF}]
    } else {
        return -1
    }
}

Při volání funkce se na místě parametru předávaného odkazem píše pouze jméno proměnné bez znaku dolar:

set retezec "Abcd"
set i 0
set kod [get_first_octet $retezec i]

Funkce s proměnným počtem parametrů[editovat | editovat zdroj]

Pokud se poslední parametr v definici funkce jmenuje args, je možné tuto funkci vyvolat s větším počtem parametrů, než je uvedeno v definici. Parametr args pak bude obsahovat seznam všech zbývajících parametrů, který lze zpracovávat funkcemi uvedenými v části Práce se seznamy.

Funkce vracející více hodnot[editovat | editovat zdroj]

Pokud má funkce vracet více hodnot, lze je vrátit v podobě seznamu, který lze zkonstruovat funkcí list:

return [list "Error" "Soubor $filename nelze číst"]

Vrácenou hodnotu lze zpracovávat pomocí funkcí uvedených v části Práce se seznamy.

Různé příkazy a funkce[editovat | editovat zdroj]

Seznam dostupných příkazů (včetně uživatelem nadefinovaných funkcí) lze vypsat příkazem:

join [lsort [info commands]] "\n"

Přestože v Tcl je každá funkce zároveň příkazem a naopak příkaz často vrací nějakou hodnotu – například příkazy incr a append vracejí novou hodnotu použité proměnné – v následujícím textu jsou rozlišovány funkce (které budou v programu použity v hranatých závorkách) od celých příkazů.

Práce se seznamy[editovat | editovat zdroj]

Seznam je v tcl libovolný řetězec, v němž jsou jednotlivé prvky odděleny mezerami. Pokud prvky seznamu obsahují mezery, Tcl je uzavírá do složených závorek. Pomocí složených závorek lze velmi jednoduše vytvářet víceúrovňové konstantní seznamy, např.

set slovnicek {
    {{učit} {teach taught taught}}
    {{učit se} {learn {learnt learned} {learnt learned}}}
}

Pro vytváření seznamů obsahujících hodnoty proměnných a výrazů lze použít příkaz list nebo subst.

Jednotlivé prvky lze vybírat pomocí funkce lindex.

  • list [ hodnota ... ] – funkce vrací seznam tvořený zadanými prvky; oproti předchozímu příkladu mohou jednotlivé argumenty obsahovat proměnné nebo být tvořeny výrazy
  • llength seznam – funkce vrací počet prvků v seznamu – llength "abc 2 xyz" vrací 3
  • lindex seznam číslo_prvku – funkce vrací zadaný prvek seznamu (prvky se číslují od 0) – lindex {a b c} 2 vrací c; prvek lze kromě čísla zadat i řetězcem end (konec řetězce) nebo ve tvaru číslo+číslo, číslo-číslo, end+číslo nebo end-číslo (zápis pozice nesmí obsahovat mezery)
  • lset seznam index hodnota – příkaz nastaví prvek seznamu se zadaným indexem na zadanou hodnotu
  • lreplace seznam n1 n2 [ hodnota ... ] – příkaz nahradí prvky n1n2 seznamu zadanými hodnotami (počet vypouštěných a vkládaných prvků nemusí souhlasit)
  • lappend proměnná [ hodnota ... ] – příkaz připojí zadané hodnoty na konec seznamu v zadané proměnné (a vrátí výsledný seznam)
  • lsearch [ -volby ... ] seznam vzorek – funkce vrátí index prvního prvku seznamu, který vyhovuje zadanému vzorku; s volbou -regexp je vzorek považován za regulární výraz, s volbou -glob za žolíkový výraz, s volbou -exact se provádí přesné porovnání (implicitně řetězců, je-li uvedena navíc volba -integer, pak celých čísel, s volbou -real čísel s pohyblivou řádovou čárkou)
  • split řetězec oddělovač – funkce vrátí seznam tvořený řetězcem rozděleným na části v místech oddělovačů
  • join seznam oddělovač – funkce spojí prvky seznamu pomocí oddělovačů a vrátí jako jeden řetězec
  • foreach { seznam_proměnných } { seznam } { příkazy } – příkaz realizující cyklus přes celý seznam; při každém průchodu zpracuje tolik položek seznamu, kolik proměnných je v seznam_proměnných a přiřadí je zadaným proměnným; příkazy se provádí opakovaně, dokud se nevyčerpají všechny prvky seznamu; pokud se v posledním průchodu nedostává hodnot pro všechny proměnné, naplní zbytek proměnných prázdnými řetězci; v těle cyklu lze používat příkazy break a continue.

Příkaz foreach lze použít pro uložení několika prvních hodnot seznamu do proměnných. Například uložení pro uložení prvního prvku seznamu do proměnné var1 a třetího prvku do var3 (druhý prvek, o který nestojíme, se uloží do proměnné -):

foreach {var1 - var3} seznam break

Práce s řetězci[editovat | editovat zdroj]

  • string length řetězec – funkce vrací délku řetězce ve znacích
  • string bytelength řetězec – funkce vrací délku řetězce v bytech
  • string index řetězec pozice – funkce vrací znak na dané pozici řetězce (číslováno od 0); pozici lze kromě čísla zadat i řetězcem end (konec řetězce) nebo ve tvaru číslo+číslo, číslo-číslo, end+číslo nebo end-číslo (zápis pozice nesmí obsahovat mezery)
  • string range řetězec from to – funkce vrací podřetězec od pozice from do pozice to včetně (číslováno od 0); from i to lze zadat stejně jako pozici ve string index
  • string first vzorek řetězec [ start ] – funkce vrací pozici prvního výskytu řetězce vzorek v zadaném řetězci od pozice start (číslováno od 0); při neúspěchu vrátí -1
  • append proměnná seznam – příkaz spojí všechny prvky seznamu do jednoho řetězce (nic mezi ně nevkládá) a ten připojí na konec obsahu proměnné
  • string map mapa řetězec – funkce vrátí řetězec vzniklý z posledního parametru nahrazením podřetězců podle mapy; mapa je seznam dvojic podřetězec náhrada; nahrazuje vždy první nalezený podřetězec, nikoli nejdelší
  • string reverse řetězec – funkce vrací zadaný řetězec pozpátku
  • string repeat řetězec počet – funkce vrací řetězec vzniklý zadaným počtem opakování zadaného řetězce
  • string compare [ -nocase ] [ -length n ] řetězec1 řetězec2 – porovná řetězce a vrátí -1 (řetězec1 je před řetězec2), 0 (řetězce jsou stejné) nebo 1

Regulární výrazy[editovat | editovat zdroj]

  • regexp [ volby ] reg_výraz řetězec [ proměnná ... ] – funkce vrátí jedničku, pokud zadaný řetězec vyhovuje regulárnímu výrazu reg_výraz; pokud jsou uvedeny proměnné, uloží se do první podřetězec, na který byl napasován celý regulární výraz, do dalších podřetězce, které byly napasovány na podvýrazy zapsané v reg_výraz v kulatých závorkách; volby mohou být
    • -nocase – nerozlišují se velká a malá písmena;
    • -start pozice – shoda se hledá až od zadané pozice
    • -indices – do proměnných se neukládají podřetězce ale dvojice čísel, udávající počáteční a koncovou pozici v řetězci; podřetězec lze získat pomocí string range řetězec [lindex $pos 0] [lindex $pos 1], kde pos je jméno proměnné, do které byla uložena dvojice pozic, která nás zajímá; pro Tcl od verze 8.5 lze použít string range řetězec {*}$pos; prefix {*} zajistí, že jednotlivá slova z proměnné $pos budou považována za samostatné parametry příkazu string range
  • regsub [volby] reg_výraz řetězec náhrada výsledek – funkce vrátí počet úspěšných nahrazení podřetězců vyhovujících reg_výraz v zadaném řetězci výrazem náhrada; do parametru výsledek uloží výsledek nahrazování; nejpoužívanější volbou je -all, která znamená, že se mají nahrazovat všechny nalezené výskyty, jinak se provede náhrada pouze prvního výskytu

Práce se soubory[editovat | editovat zdroj]

  • open jméno – funkce otevře nebo vytvoří soubor a vrátí manipulátor souboru
  • close manipulátor – funkce zavře soubor
  • puts [manipulátor] řetězec – příkaz zapíše zadaný řetězec do souboru
  • gets [manipulátor] – funkce načte jeden řádek ze souboru a vrátí ho
  • read manipulátor [délka] – funkce načte blok zadané délky ze souboru
  • fconfigure [manipulátor] parametry – příkaz nastaví režim práce se souborem (např. nebufferovaný, bez čekání, binární bez konverzí kódování a konců řádků)

Konverze dat[editovat | editovat zdroj]

  • format formát hodnota [ ... ] – funkce vrací řetězec formát vyplněný v místech formátovacích direktiv zadanými hodnotami – jako funkce sprintf v jazyce C
  • scan řetězec formát [proměnná [ ... ]] – funkce načítá z řetězce hodnoty zadané formátem a plní jimi proměnné jako funkce sscanf v jazyce C; vrací počet naplněných proměnných
  • binary format formát řetězec – funkce vrací řetězec vzniklý interpretací zadaného řetězce zadaným formátem; binary format B* 0100000101000010 vrací AB, protože 01000001 je binární zápis kódu písmene A a 01000010 binární zápis kódu písmene B
  • binary scan vstup formát výstup – příkaz uloží do proměnné $výstup hodnotu vzniklou interpretací vstupu zadaným formátembinary scan $line B* bitstring uloží do $bitstring binární zápis obsahu proměnné $line; binary scan ABC12 H* output; puts $output vypíše reprezentaci znaků v šestnáctkové soustavě 4142433132
  • encoding convertto výstupní_kódování vstup – funkce vrací vstup zkonvertovaný do zadaného kódování
  • encoding convertfrom vstupní_kódování vstup – funkce vrací vstup zkonvertovaný ze zadaného kódování – pro konverzi z UTF-16 do UTF-8 je nutné použít [encoding convertto utf-8 [encoding convertfrom unicode $vstup]]

Reference[editovat | editovat zdroj]

  1. LERDORF, Rasmus. PHP on Hormones – history of PHP presentation by Rasmus Lerdorf given at the MySQL Conference in Santa Clara, California [online]. The Conversations Network, 2007-04-26. Dostupné online.  
  2. Windows PowerShell : PowerShell and WPF: WTF
  3. tclreadline; GNU readline for interactive tcl shells [online]. [cit. 2017-05-09]. Dostupné online.  

Externí odkazy[editovat | editovat zdroj]

(anglicky)
(česky)