Tento obrázek je považován za nejlepší na Wikipedii v jazyce angličtina (Featured pictures), a tedy splňuje tamější pravidla pro nejlepší obrázky. Pokud se domníváte, že by tento soubor měl být zařazen i mezi nejlepší soubory na Commons, můžete ho nominovat. Pokud máte nějaký podobně kvalitní soubor, který lze zveřejnit pod vhodnou licencí, určitě ho načtěte, označte a nominujte.

Raytraced image of two jack plugs, one mono, the other stereo. Numbers on details added, and image cropped afterwards in a graphics software package.
Numbers indicate:

1. Sleeve - usually ground
2. Ring - Right-hand channel for stereo signals, negative phase for balanced mono signals, power supply for power-requiring mono signal sources
3. Tip - Left-hand channel for stereo signals, positive phase for balanced mono signals, signal line for unbalanced mono signals
4. Isolating rings

Rendered with POV-Ray (see http://www.povray.org/) - below is the scene description for this image

 /*
 ======================================
 "Jack"- or "Tip-ring-sleeve"-type plug
 --------------------------------------
 Created by Søren Peo Pedersen - see my
 user page at
 http://da.wikipedia.org/wiki/Bruger:Peo
 ======================================
 */
 
 #declare Metallic=texture {   // Texture for
     pigment {color rgb .3}    // metallic parts
     finish {                  // of the jacks
         reflection .7
         phong 1
         phong_size 60
         ambient .5
         diffuse .5
         metallic
         }
     }
 
 #declare Isolator=texture {   // Texture for insu-
     pigment {color rgb 0}     // lator between tip,
     finish {                  // ring, and sleeve
         reflection .5
         phong 1
         phong_size 20
         }
     }
 
 #declare Spotty=pigment {     // Spotty pigment
         bozo                  // for surroundings,
         color_map {           // to enhance the
             [0 color rgb 0]   // reflective parts
             [1 color rgb 1]   // of the plugs
             }
         scale .3
         }
 
 sky_sphere {                  // Make for "surroundings"
     pigment {
         gradient y
         pigment_map {
             [0.0 color rgb 1.0]
             [0.12 color rgb 1.0]
             [0.2 Spotty]
             [1.0 Spotty]
             }
         translate <0,-.5,0>
         scale 2            
         rotate <-90,0,0>
         }
     }
 
 #macro Jack_plug(StereoFlag)  // Common macro for mono & stereo plug
 
 union {             // Cable extending from
   sphere_sweep {    // rear end of the plugs
     cubic_spline,5,
     <0,100,0>,2.7
     <0,-40,0>,2.7
     <20,-90,-10>,2.7
     <-0,-240,-40>,2.7
     <-0,-290,-90>,2.7
     
     pigment {color rgb .5}
     finish {
       ambient .5
       diffuse .5
       }
     }
     
     // Conical "sleeve" where the cable enters the jack:
     cone {<0,-24.5,0>,5,<0,-40,0>,3 pigment {color rgb .5}}
     torus {3,1 translate <0,-40,0> pigment {color rgb .5}}
     
     // Cylindrical, dark "body"
     cylinder {<0,-24.5,0>,<0,-24,0>,5.5 texture {Isolator pigment {color rgb .2}}}
     torus {5.5,.5 translate <0,-24,0> texture {Isolator pigment {color rgb .2}}}
     cylinder {<0,-1,0>,<0,-24,0>,6 texture {Isolator pigment {color rgb .2}}}
     torus {5.5,.5 translate <0,-1,0> texture {Isolator pigment {color rgb .2}}}
     
     cone {0,4.5,<0,-.5,0>,5.5 texture {Metallic}} // Metal "base" of plug
     
     cylinder {<0,0,0>,<0,   // "Sleeve" part of the plug
       #if(StereoFlag !=0) 15.3 #else 21.2 #end
       ,0>,3.1
       texture {Metallic}
       }
     
     #if (StereoFlag != 0) // If rendering the stereo (3-way) version:
       cylinder {<0,15.3,0>,<0,16.3,0>,3.1 texture {Isolator}}   // Add an extra, narrow isolator
       cylinder {<0,16.3,0>,<0,21.2,0>,3.1 texture {Metallic}}   // and the ring
     #end
     
     cylinder {<0,21.2,0>,<0,22.8,0>,3.1 texture {Isolator}}       // Wide isolator
     // Cylindrical section right behind the tip:
     cylinder {<0,22.8,0>,<0,23.5066144,0>,3.1 texture {Metallic}}
     
     merge {   // The tip with "neck" and conical end
         cone {<0,31.2,0>,0.8,<0,27.7156,0>,3.0111}
         torus {2.5,.6 translate <0,27.4,0>}
         cone {<0,23.6,0>,0.8,<0,27.0844,0>,3.0111}
         
         difference {
             cylinder {0,<0,1.638,0>,2.866144}
             torus {2.866144,1.066144 translate <0,1.066144,0>}
             translate <0,23.8,0>                    
             }
         torus {2.8066144,0.2933856 translate <0,23.5066144,0>}
         
         texture {Metallic}
         }
     }
 
 #end  // End of macro
 
 // Show a mono and a stereo jack:
 #object {Jack_plug(1) rotate <0,-20,0> rotate <-40,0,-100> translate <0,11,0>}
 #object {Jack_plug(0) rotate <0,20,0> rotate <-40,0,-100> translate <0,-8,0>}
 
 light_source {<-10000,5000,-10000> color rgb 2}            
 camera {location <0,0,-80> look_at <0,0,0> angle 50}

Já, držitel autorských práv k tomuto dílu, ho tímto zveřejňuji za podmínek následujících licencí:

Tento dokument smí být kopírován, šířen nebo upravován podle podmínek Svobodné licence GNU pro dokumenty verze 1.2 nebo libovolné vyšší verze publikované nadací Free Software Foundation. Dokument nemá neměnné části ani texty na předním či zadním přebalu. Kopie textu licence je k dispozici v oddíle nazvaném GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	Tento soubor podléhá licenci Creative Commons Uveďte autora-Zachovejte licenci 3.0 Unported
	Dílo smíte: šířit – kopírovat, distribuovat a sdělovat veřejnosti upravovat – pozměňovat, doplňovat, využívat celé nebo částečně v jiných dílech Za těchto podmínek: uveďte autora – Máte povinnost uvést autorství, poskytnout odkaz na licenci a uvést, pokud jste provedli změny. Toho můžete docílit jakýmkoli rozumným způsobem, avšak ne způsobem naznačujícím, že by poskytovatel licence schvaloval nebo podporoval vás nebo vaše užití díla. zachovejte licenci – Pokud tento materiál jakkoliv upravíte, přepracujete nebo použijete ve svém díle, musíte své příspěvky šířit pod stejnou nebo slučitelnou licencí jako originál.
	Tato licenční šablona byla k tomuto souboru přidána v rámci změny licencování.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

Můžete si zvolit libovolnou z těchto licencí.